home *** CD-ROM | disk | FTP | other *** search
/ Visual Basic Source Code / Visual Basic Source Code.iso / vbsource / dial / autodial.frm next >
Text File  |  1996-09-12  |  4KB  |  125 lines
  1. VERSION 4.00
  2. Begin VB.Form Form1 
  3.    BorderStyle     =   3  'Fixed Dialog
  4.    Caption         =   "Auto-Dial"
  5.    ClientHeight    =   1830
  6.    ClientLeft      =   3765
  7.    ClientTop       =   3720
  8.    ClientWidth     =   3510
  9.    Height          =   2235
  10.    Left            =   3705
  11.    LinkTopic       =   "Form1"
  12.    MaxButton       =   0   'False
  13.    MinButton       =   0   'False
  14.    ScaleHeight     =   1830
  15.    ScaleWidth      =   3510
  16.    ShowInTaskbar   =   0   'False
  17.    Top             =   3375
  18.    Width           =   3630
  19.    Begin VB.CommandButton cmdExit 
  20.       Caption         =   "E&xit"
  21.       Height          =   375
  22.       Left            =   1920
  23.       TabIndex        =   3
  24.       Top             =   1200
  25.       Width           =   1215
  26.    End
  27.    Begin VB.CommandButton cmdDial 
  28.       Caption         =   "&Dial..."
  29.       Height          =   375
  30.       Left            =   360
  31.       TabIndex        =   2
  32.       Top             =   1200
  33.       Width           =   1215
  34.    End
  35.    Begin VB.TextBox txtNumber 
  36.       Height          =   285
  37.       Left            =   120
  38.       TabIndex        =   0
  39.       Top             =   600
  40.       Width           =   3255
  41.    End
  42.    Begin VB.Label Label1 
  43.       Caption         =   "&Phone Number:"
  44.       Height          =   255
  45.       Left            =   120
  46.       TabIndex        =   1
  47.       Top             =   360
  48.       Width           =   1935
  49.    End
  50. End
  51. Attribute VB_Name = "Form1"
  52. Attribute VB_Creatable = False
  53. Attribute VB_Exposed = False
  54. 'AutoDial - Telephone dialer demo program
  55. 'Copyright (c) 1996 SoftCircuits
  56. 'Redistributed by Permission.
  57. '
  58. 'This Visual Basic 4.0 example program demonstrates how an application
  59. 'can dial a telephone number under Windows 95 using Assisted Telephony
  60. 'which is a subset of TAPI. This code is simple because it relies on a
  61. 'call manager applet to perform the actual dialing.
  62. '
  63. 'This program may be distributed on the condition that it is
  64. 'distributed in full and unchanged, and that no fee is charged for
  65. 'such distribution with the exception of reasonable shipping and media
  66. 'charged. In addition, the code in this program may be incorporated
  67. 'into your own programs and the resulting programs may be distributed
  68. 'without payment of royalties.
  69. '
  70. 'This example program was provided courtesy of:
  71. ' SoftCircuits Programming
  72. ' P.O. Box 16262
  73. ' Irvine, CA 92623
  74. ' http://www.softcircuits.com
  75. Option Explicit
  76.  
  77. Private Declare Function tapiRequestMakeCall& Lib "TAPI32.DLL" (ByVal DestAddress$, ByVal AppName$, ByVal CalledParty$, ByVal Comment$)
  78. Private Const TAPIERR_NOREQUESTRECIPIENT = -2&
  79. Private Const TAPIERR_REQUESTQUEUEFULL = -3&
  80. Private Const TAPIERR_INVALDESTADDRESS = -4&
  81.  
  82.  
  83. Private Sub cmdDial_Click()
  84.     Dim buff As String
  85.     Dim nResult As Long
  86.  
  87.     'Invoke tapiRequestMakeCall. If tapiRequestMakeCall returns 0, the
  88.     'request has been accepted. It is up to the call manager application
  89.     'to do any further work. The second-to-last argument should be
  90.     'changed to be the name of the person you are dialing.
  91.     nResult = tapiRequestMakeCall&(Trim$(txtNumber), CStr(Caption), "Test Dial", "")
  92.     'Display message if error
  93.     If nResult <> 0 Then
  94.         buff = "Error dialing number : "
  95.         Select Case nResult
  96.             Case TAPIERR_NOREQUESTRECIPIENT
  97.                 buff = buff & "No Windows Telephony dialing application is running and none could be started."
  98.             Case TAPIERR_REQUESTQUEUEFULL
  99.                 buff = buff & "The queue of pending Windows Telephony dialing requests is full."
  100.             Case TAPIERR_INVALDESTADDRESS
  101.                 buff = buff & "The phone number is not valid."
  102.             Case Else
  103.                 buff = buff & "Unknown error."
  104.         End Select
  105.         MsgBox buff
  106.     End If
  107. End Sub
  108.  
  109. Private Sub cmdExit_Click()
  110.     Unload Me
  111. End Sub
  112.  
  113. Private Sub Form_Load()
  114.     Move (Screen.Width - Width) \ 2, (Screen.Height - Height) \ 2
  115.     EnableDial
  116. End Sub
  117.  
  118. Private Sub txtNumber_Change()
  119.     EnableDial
  120. End Sub
  121.  
  122. Private Sub EnableDial()
  123.     cmdDial.Enabled = Len(Trim$(txtNumber)) > 0
  124. End Sub
  125.